PROGRAM: CdKN
'Kjellström and Nordberg (1978) MODEL FOR Cd IN HUMANS '
'program allows you to estimate pharmacokinetics of '
'Cd IN LINEAR MULTICOMPARTMENT SYSTEM IN HUMAN, '
'TIME IS IN [DAYS], Cd IS IN [micrograms] PER AVERAGE '
'INDIVIDUAL 70 kg BW '
'ACSL codes by Janusz Z. Byczkowski, TN & A, 09/5/1998 '
'--------------------------------------------------------------'
INITIAL

CONSTANT TSTOP =25550. $'time for run termination [day] '
CONSTANT POINTS =100. $'points per run '
CINT = TSTOP/POINTS $'communication interval [day] '
'Kjellstrom and Nordberg (1978) PARAMETERS '
CONSTANT AIR = 3. $'Cd intake from smoking 20 cig/day (ug/day)'
CONSTANT SMOK= 1. $'Defaulted inhalation exposure (switch) '
CONSTANT ENDSM=9855. $'Stop inhalation exposure (day) '
CONSTANT G = 16. $'Cd intake from diet and water (ug/day)'
CONSTANT C1 = 0.1 $'cigarette smoke, or factory dust =0.7 '
CONSTANT C2 = 0.4 $'cigarette smoke, or factory dust =0.13'
CONSTANT C3 = 0.05 $'rate constant (1/day) '
CONSTANT C4 = 0.005 $'rate constant (1/day) '
CONSTANT C5 = 0.048 $'ratio '
CONSTANT C6 = 0.05 $'rate constant (1/day) '
CONSTANT C7 = 0.25 $'ratio '
CONSTANT C8 = 1. $'microgram '
CONSTANT C9 = 0.44 $'ratio '
CONSTANT C10 = 0.00014 $'rate constant (1/day) '
CONSTANT C11 = 0.27 $'ratio '
CONSTANT C12 = 0.25 $'ratio '
CONSTANT C13 = 0.00003 $'rate constant (1/day) '
CONSTANT C14 = 0.00016 $'rate constant (1/day) '
CONSTANT C15 = 0.00005 $'rate constant (1/day) '
CONSTANT C16 = 0.012 $'rate constant (1/day) '
CONSTANT C17 = 0.95 $'decreases from age 30 to 80 by 33% '
CONSTANT C18 = 0.00001 $'rate constant (1/day) '
CONSTANT C19 = 0.00014 $'rate constant (1/day) increases from '

'age 30 with C21 each year ' CONSTANT CX = 0.04 $'ratio '
CONSTANT C20 = 0.1 $'ratio '
CONSTANT C21 = 0.0000011 $'rate constant (1/day) '
CONSTANT CORTX=1.51 $'Ratio of kidney/cortex concentration '
CONSTANT ALW = 1500. $'Average liver weight (g) '
CONSTANT AKW = 281. $'Average kidney weight (g) '
CONSTANT ABV = 70. $'Average blood volume (ml/kg) '
CONSTANT ABSG= 1.06 $'Average blood specific gravity (g/ml) '
CONSTANT ADUA= 1.0 $'Average daily urine excretion adult(L)'
CONSTANT ADUO= 0.9 $'Average daily urine excretion old (L) '
CONSTANT ADUC= 0.5 $'Average daily urine excretion child(L)'
CONSTANT BW = 70. $'Body weight (kg) '
CONSTANT ATW = 67467. $'Weight of other tissues (g) '
Asm = AIR * SMOK $'Smoking/nonsmoking switch '

END $'end of initial '
DYNAMIC

ALGORITHM IALG = 2 $'Gear method for stiff systems '
DERIVATIVE

PROCEDURAL
IF (t.LE.10950.) C17t = C17
IF (t.GT.10950.) C17t = C17*(1.198 - t*(1.8E-05))
IF (T.LT.7300.) A = 0. $'no smoking at age < 20 y '
IF (T.GE.7300.) A = Asm $'start smoking at age 20 y '
IF (T.GT.ENDSM) A=0. $'stop smoking at age ENDSM/365 >=y'
IF (T.LE.3650.) ADU = ADUC
IF (T.GT.3650.) ADU = ADUA
IF (T.GE.21900.)ADU = ADUO
END $'END OF PROCEDURAL '
'*****************MODEL FOR CADMIUM ***************************'
'LUNG '
E1 = C2*A $'rate exposing the lung (ug/day) '
E1t = E1 -C3*AE1t -C4*AE1t $'rate of loading (ug/day) '
AE1t= INTEG(E1t,0.) $'amount remaining in the lung (ug) '
AAt = INTEG(E1,0.) $'amount introduced (ug) '
Rgo= AE1t*(C3+C4) $'rate of absorption (ug/day) '
Gone=Integ(Rgo,0.) $'amount gone (ug) '
E1bal = AAt - AE1t - Gone $'check of mass conservation: E1bal=0'

'INTESTINE '
E2 = C5*(G + C1*A +C4*AE1t) $'rate loading GI tract (ug/day) '
E2t= E2 - C6*AE2t $'rate of change GI tract (ug/day)'
AE2t = INTEG(E2t,0.) $'amount remaining in the GI (ug) '
Gt = INTEG(G,0.) $'amount introduced with diet (ug)'

'DAILY ABSORBED AMOUNTS OF Cd '
I = C3*AE1t +C6*AE2t $'rate of internal uptake (ug/day) '
AIt = INTEG(I,0.) $'internal I amount received (ug) '

'Daily absorbed amounts at steady state in a long term exposure'
' (ug/day)'
IssAG = A*C2*C3/(C3+C4)+G*C5+(A*C1+A*C2*C4/(C3+C4))*C5 $'A & G'
IssA = A*(C2*0.91+C5*C1+C5*0.09) $'by inhalation only (ug/day)'

PROCEDURAL
IF (I2t.GE.C8) I2t = C8
END $'END OF PROCEDURAL '

I2t = C7*I $'rate loading MTN for values =I1t = I - I2t $'rate unloading to plasma (ug/day) '

'BLOOD COMPARTMENT 1 PLASMA '
B1=I1t +C10*ATt +C13*ALt +C18*AKt$'rate loading plasma (ug/day)'

B1t= B1 - B1*CX $'rate of change in 1 (ug/day)'
AB1t = INTEG(B1t,0.) $'amount in plasma (ug) '

'Blood Compartment 2 including ERYTHROCYTES '
B2 = B1t*(1-C9-C11-C12) $'rate loading blood 2 (ug/day) '
B2t = B2 - C16*AB2t $'rate of change in blood 2 (ug/day) '
AB2t = INTEG(B2t,0.) $'amount in blood 2 (ug) '
BLDCd= AB2t/5000 $'estimate of Cd blood conc. (ug/ml) '

'BLOOD COMPARTMENT 3 METALLOTHIONEIN '
B3t = I2t +C16*AB2t +C14*ALt $'rate loading MTN (ug/day) '
AB3t =INTEG(B3t,0.) $'amount bound to metallothionein etc.(ug)'

'AMOUNT IN WHOLE BLOOD (ug) '
B4t = B2t +C20*(B1t + B3t) $'rate of change in blood ug/day) '
AB4t= INTEG(B4t,0.) $'amount in whole blood (ug) '
CBt = AB4t/(ABV*BW*ABSG) $'Conc in whole blood (ug/g) '

'OTHER TISSUES '
OT = C9*B1t $'rate loading other tissues (ug/day) '
Tt = OT- ATt*C10 $'rate of change in other tissues (ug/day)'
ATt = INTEG(Tt,0.) $'amount in other tissue (ug) '
ATBW= ATt/ATW $'concentration in other tissue (ug/g) '

'LIVER '
L = C12*B1t $'rate loading liver (ug/day) '
Lt = L -ALt*(C13+C14+C15) $'rate of change in liver (ug/day) '
ALt = INTEG(Lt,0.) $'amount in liver (ug) '
ALBW= ALt/ALW $'concentration in liver (ug/g) '

PROCEDURAL
IF (t.LT.10950.) n = 0.
IF (t.GE.10950.) n = (t - 10950.)/365
END $'END OF PROCEDURAL '

'KIDNEY '
C19t= C19 + C21*n
K = C17t*B3t $'rate loading kidney (ug/day) '
Kt = K - C18*AKt -C19t*AKt $'rate of change in kidney (ug/day)'
AKt = INTEG(Kt,0.) $'amount in kidney (ug) '
AKBW= AKt/AKW $'concentration in kidney (ug/g) '
CKBW= AKBW*CORTX $'concentration in kidney cortex (ug/g)'

'WHOLE BODY '
Wt = B4t +Lt +Kt +Tt +E1t +E2t $'amount in whole body (ug/day)'
WBW= Wt/BW $'concentration (ug/kg) '

'FECES EXCRETION '
Ft = C11*B1t + C15*ALt $'rate of excretion (ug/day) '
AFt = INTEG(Ft, 0.) $'amount excreted (ug) '

'URINARY EXCRETION '
Ut = B3t*(1-C17t) +AKt*C19 $'rate of urinary excret.(ug/day)'
AUt = INTEG(Ut,0.) $'cumulated amount in urine (ug) '
CUt = Ut/ADUA $'conc. in daily urine (ug/L) '

PROCEDURAL
IF (CKBW.GT.0.) URCO=Ut/CKBW $'ratio urinary Cd/cortex Cd '
END $'end procedural '

TERMT(T.GE.TSTOP)
END $'end of derivative '
END $'end of dynamic '
END $'end of program '