PROGRAM: LIPID PEROXIDATION
 'Version 2 *SQRT* (original model: Byczkowski et al. Comp. Meth'
 'Progr. Biomed.50, 73, 1996), based on mathematical description'
 'by Tappel et al. Free. Rad. Biol. Med. 7, 361, 1989.          '
 'THE PURPOSE OF THIS PROGRAM IS TO SIMULATE PRODUCTION OF TBARS'
 'FROM PUFA IN MOUSE LIVER SLICES in vitro. **DEFAULT FOR TCE***'
 'DESCRIPTION: in press Byczkowski et al. J. Biochem. Mol.      '
 'Toxicol. 13(#4), 1999                                         '
 
INITIAL

 'PEROXIDATION PARAMETERS FOR TCE IN LIVER [0.1 g of liver]     '
 CONSTANT    IND1  =  1.0      $'inducer 1 [mcM TCE/0.1g liv]   '
 CONSTANT    PUF   =  7.0      $'Conc.PUFA[microMol/0.1 g liver]'
 CONSTANT    PXZLUF=  12.0     $'peroxidizability of PUFA-L[1/h]'
 CONSTANT    PXZHUF=  24.0     $'peroxidizability of PUFA-H[1/h]'
 CONSTANT    ANOX1 =  0.0037   $'Vit.E antiox[microMol/0.1g liv]'
 CONSTANT    ACT1  =  0.0003   $'activator1[mcM cytP450/0.1gliv]'
 CONSTANT    GSH   =  0.6      $'glutathione [mcroM/0.1 g liver]'
 CONSTANT    PXTTBA=  0.1      $'yield ofTBARS/Mol hydroperoxide'
 CONSTANT    LPUF  =  3.       $'LA-derivative PUFA[mcMol/0.1 g]'
 CONSTANT    HPUF  =  4.       $'HA-derivative PUFA[mcMol/0.1 g]'
 CONSTANT    EFANO1 = 1.       $'effectiveness of Vit.E         '
 CONSTANT    ANOXUF = 2.       $'antioxidant use factor [/mcmol]'
 CONSTANT    ANOX2 =  0.       $'non-Vit.E antiox[mcM/0.1 g liv]'
 CONSTANT    ANOX3 =  0.       $'added antioxidant[mcM/0.1g liv]'
 CONSTANT    ACACT1 = 1.       $'activity of activator 1        '
 CONSTANT    ACTDGF = 0.0014   $'activator degradation fctr /mcm'
 CONSTANT    PTIND1 = 250.     $'potency of inducer 1 [1/mcmol] '
 CONSTANT    INDLF  = 0.0001   $'inducer loss factor [1/h]      ' 
 CONSTANT    PXRATE = 0.00029  $'peroxidation rate [mcm/mcm]    '  
 CONSTANT    AUTOXF = 0.00013  $'autooxidation factor [1/h]     '
 CONSTANT    GPENZA = 1.       $'glutathione peroxidase[/mcM]   '
 CONSTANT    PXREDF = 0.17     $'hydroperoxide reduction fctr /h'
 CONSTANT    TSTOP  = 2.       $'end of simulation [h]          '
 CONSTANT    ACR    = 0.025    $'Activator degradation rate[1/h]'
 CONSTANT    PHYSPX = 0.       $'physiological levels of Hperox '
 CONSTANT    ANREG  = 0.       $'antioxidant regenerated in situ'
 CONSTANT    BCKGD  = 0.0      $'TBARS in control [mcm/0.1 g]   '
 
 !PARAMETERS FOR EXPOSURE TO SECOND CHEMICAL PROOXIDANT
 CONSTANT    EFANO2 = 0.       $'effectiveness of non-Vit.E a-o '
 CONSTANT    EFANO3 = 0.       $'effectiveness of added a-o     '
 CONSTANT    ACT2   = 0.       $'activator 2 [mcM/0.1 g liver]  '
 CONSTANT    ACACT2 = 0.       $'activity of activator 2        '
 CONSTANT    IND2   = 0.       $'inducer2[mcM chemical/0.1g liv]'
 CONSTANT    PTIND2 = 0.       $'potency of inducer 2 [1/mcmol] '
   
 'TIMING COMMANDS                                               '
 CONSTANT    POINTS = 500.
 CINT=TSTOP/POINTS

 '                 INITIALIZATION                               '
 'RESETS INITIAL CONDITIONS BEFORE PEROXIDATION                 '
 CONSTANT ACTLOS=0.          $'activator loss                   '
 CONSTANT AUTOX =0.          $'autooxidation                    '
 CONSTANT PXREDG=0.          $'Hperoxides red. by GSH peroxidase'
 CONSTANT PXLUF =0.00199     $'L-Hydroperoxides formed          '
 CONSTANT PXHUF =0.0053      $'H-Hydroperoxides formed          '
 CONSTANT PXREM =0.          $'accumulated remaining Hperoxides '
 CONSTANT TPX   =0.          $'accumlted total Hperoxides formed'
 CONSTANT ILR   =0.          $'rate of inducer loss = 0.        ' 
 
END                          $'End of Initial                   '
  
DYNAMIC
 ALGORITHM IALG = 2          $'Gear stiff method                '

DERIVATIVE

PROCEDURAL

IF (LPUFRE.LE.0) LPUFRE = 0.
IF (HPUFRE.LE.0) HPUFRE = 0.
IF (ACTLOS.GE.ACTEF)  ACTLOS = ACTEF
IF (ANOXRE.LE.1.e-10) ANOXRE = 1.e-10
IF (GSHREM.LE.0) GSHREM = 0.
IF (INDLOS.GE.INDEF)  INDLOS = INDEF
IF (PXREDA.GE.TPX) PXREDA = TPX

END     $'End of procedural                                     '

'---------------------------------------------------------------'
 '#s Correspond to equations in Tappel et al. (1989) and        '
 '   Byczkowski et al. (1996)                                   '
!VARIABLES ARE CONVERTED TO CONCENTRATIONS [micromole/0.1 g liver]   
'---------------------------------------------------------------'

 '1. Remaining polyunsaturated fatty acids                      '

 LPUFRE = LPUF - PXLUFA - AUTOXA/2
 HPUFRE = HPUF - PXHUFA - AUTOXA/2

 '2. Effective activator                                        '

 ACTEF =  ACT1*ACACT1 + ACT2*ACACT2 

 '3. Activator loss                                             '

 ACTLOS = ACTEF*ACTDGF*TPX

 '4. Remaining activator                                        '
 
 ACTREM = (ACTEF - ACTLOS)*exp(-ACR*INDREM*t)

 '5. Effective inducer                                          '

 INDEF = SQRT(IND1*PTIND1) + IND2*PTIND2

 '6. Remaining inducer                                          '

 INDREM = INDEF - INDLOS

 '6.a. Inducer loss rate                                        '

 ILR = INDEF*INDLF

 '7. Activated inducer                                          '

 ACTIND = INDREM*ACTREM

 '8. Effective antioxidant                                      '

 ANOXEF = ANOX1*EFANO1 + ANOX2*EFANO2 + ANOX3*EFANO3

 '9. Remaining antioxidant                                      '
 
 ANOXRE = ANOXEF - ANOXEF*TPX*ANOXUF + ANREG*exp(-ANOXR*t)

 '10.Hydroperoxides formed by action of activated inducer on    ' 
 '                                                          PUFA' 
 
 PXLUF = LPUFRE*PXZLUF*ACTIND*PXRATE/ANOXRE 
 PXHUF = HPUFRE*PXZHUF*ACTIND*PXRATE/ANOXRE
  
 '12.Autooxidation                                              '

 AUTOX = (LPUFRE + HPUFRE)*AUTOXF*TPX/ANOXRE

 '14.Accumulated total hydroperoxides formed                    '

 TPX = AUTOXA + PXLUFA + PXHUFA + PHYSPX     

 '15.Remaining glutathione                                      '

 GSHREM = GSH - PXREDA

 '16.Hydroperoxides reduced by glutathione peroxidase           '

 PXREDG = PXREM*GPENZA*GSHREM*PXREDF

 '18.Accumulated remaining hydroperoxides                       '

 PXREM = TPX - PXREDA

 '19.Amount of TBARS from accumulated remaining hydroperoxides  ' 
 
 TBARS = PXREM*PXTTBA + BCKGD

 '6b.   Inducer lost over time                                  '

 INDLOS = INTEG(ILR,0.)
 
 '11.Accumulated hydroperoxides formed by action of activated   '
 '   inducer on PUFA                                            '

 PXLUFA = INTEG(PXLUF, 0.)

 PXHUFA = INTEG(PXHUF, 0.)

 '13.Accumulated autooxidation                                  '

 AUTOXA = INTEG(AUTOX, 0.)

 '17.Accumulated hydroperoxides reduced by glutathione          ' 
 '                                                    peroxidase'
 
 PXREDA = INTEG(PXREDG, 0.)
 '- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - '
 TERMT(T.GE.TSTOP)           $'Termination at TSTOP             '
END                          $'End of derivative                '
END                          $'End of dynamic                   '
'^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^'
TERMINAL                   $'Resets parameters to initial values'
ACTREM = ACTEF
INDREM = INDEF
ANOXRE = ANOXEF
END                        $'End of terminal                    '
'^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^'
END                        $'End of program                     '